spring-security/core/core.gradle

// Core build file

dependencies {
    compile 'aopalliance:aopalliance:1.0',
            "net.sf.ehcache:ehcache:$ehcacheVersion",
            "org.springframework:spring-aop:$springVersion",
            "org.springframework:spring-beans:$springVersion",
            "org.springframework:spring-context:$springVersion",
            "org.springframework:spring-expression:$springVersion",
            "org.springframework:spring-jdbc:$springVersion",
            "org.springframework:spring-tx:$springVersion",
            "org.aspectj:aspectjrt:$aspectjVersion",
            'javax.annotation:jsr250-api:1.0'

    testCompile 'commons-collections:commons-collections:3.2',
                "org.springframework:spring-test:$springVersion",
                "org.slf4j:jcl-over-slf4j:$slf4jVersion"

    testRuntime "hsqldb:hsqldb:$hsqlVersion",
                "cglib:cglib-nodep:$cglibVersion"
}

// jdkVersion = System.properties['java.version']
// isJdk6 = jdkVersion >= '1.6'
int maxAESKeySize = javax.crypto.Cipher.getMaxAllowedKeyLength('AES')

test {
    systemProperties['springSecurityVersion'] = version
    systemProperties['springVersion'] = springVersion

    if (maxAESKeySize < 256) {
        logger.warn("AES keysize limited to $maxAESKeySize, skipping EncryptorsTests")
        exclude '**/EncryptorsTests.class'
    }
}