spring-security/config/config.gradle

// Config Module build file

apply plugin: 'groovy'
apply plugin: 'trang'

compileTestJava.dependsOn(':spring-security-core:compileTestJava')

configurations {
    // GRADLE-1124
    compile.extendsFrom = []
    testCompile.extendsFrom groovy
}

dependencies {
    // NB: Don't add other compile time dependencies to the config module as this breaks tooling
    compile project(':spring-security-core'),
            project(':spring-security-web'),
            project(':spring-security-openid'),
            project(':spring-security-ldap'),
            "org.aspectj:aspectjweaver:$aspectjVersion",
            'aopalliance:aopalliance:1.0',
            "org.springframework:spring-aop:$springVersion",
            "org.springframework:spring-context:$springVersion",
            "org.springframework:spring-web:$springVersion",
            "org.springframework:spring-beans:$springVersion",
            "org.springframework:spring-jdbc:$springVersion",
            "org.springframework:spring-tx:$springVersion",
            "org.springframework.ldap:spring-ldap-core:$springLdapVersion"
            compile('org.openid4java:openid4java-nodeps:0.9.6') {
                exclude group: 'com.google.code.guice', module: 'guice'
            }
            compile 'com.google.inject:guice:2.0'
            compile apacheds_libs

    provided "org.apache.tomcat:tomcat-servlet-api:$servletApiVersion"

    groovy 'org.codehaus.groovy:groovy:1.8.7'

    testCompile project(':spring-security-ldap'),
                project(':spring-security-openid'),
                project(':spring-security-cas'),
                project(':spring-security-core').sourceSets.test.output,
                'javax.annotation:jsr250-api:1.0',
                "org.springframework.ldap:spring-ldap-core:$springLdapVersion",
                "org.springframework:spring-expression:$springVersion",
                "org.springframework:spring-jdbc:$springVersion",
                "org.springframework:spring-orm:$springVersion",
                "org.springframework:spring-tx:$springVersion",
                'org.spockframework:spock-core:0.6-groovy-1.8',
                "org.slf4j:jcl-over-slf4j:$slf4jVersion",
                "org.hibernate.javax.persistence:hibernate-jpa-2.0-api:1.0.1.Final",
                "org.hibernate:hibernate-entitymanager:4.1.0.Final",
                powerMockDependencies
    testCompile('org.openid4java:openid4java-nodeps:0.9.6') {
       exclude group: 'com.google.code.guice', module: 'guice'
    }


    testRuntime "hsqldb:hsqldb:$hsqlVersion",
                "cglib:cglib-nodep:2.2"
}

test {
    inputs.file file("$rootDir/docs/manual/src/docbook/appendix-namespace.xml")
}

integrationTest {
    systemProperties['apacheDSWorkDir'] = "${buildDir}/apacheDSWork"
}

rncToXsd {
    rncDir = file('src/main/resources/org/springframework/security/config/')
    xsdDir = rncDir
    xslFile = new File(rncDir, 'spring-security.xsl')
}

build.dependsOn rncToXsd