spring-security/saml2/saml2-service-provider/core/saml2-service-provider-core.gradle

buildscript {
	repositories {
		maven { url 'https://repo.spring.io/plugins-release' }
	}
	dependencies {
		classpath 'io.spring.gradle:propdeps-plugin:0.0.10.RELEASE'
	}
}

plugins {
	id 'java-library'
	id 'io.spring.convention.repository'
	id 'io.spring.convention.management-configuration'
	id 'io.spring.convention.dependency-set'
	id 'io.spring.convention.checkstyle'
	id 'io.spring.convention.tests-configuration'
	id 'io.spring.convention.integration-test'
	id 'propdeps'
}

configurations {
	classesOnlyElements {
		canBeConsumed = true
		canBeResolved = false
	}
}

artifacts {
	classesOnlyElements(compileJava.destinationDir)
}

repositories {
	maven { url "https://build.shibboleth.net/nexus/content/repositories/releases/" }
}

dependencies {
	constraints {
		management("org.opensaml:opensaml-core:3.+")
		management("org.opensaml:opensaml-saml-api:3.+")
		management("org.opensaml:opensaml-saml-impl:3.+")
	}

	api project(':spring-security-core')
	api project(':spring-security-web')

	provided("org.opensaml:opensaml-core")
	provided("org.opensaml:opensaml-saml-api")
	provided("org.opensaml:opensaml-saml-impl")

	provided 'javax.servlet:javax.servlet-api'

	testImplementation 'com.squareup.okhttp3:mockwebserver'
}